SNMP Trap Software Development Kit to send traps using VBScript

ActiveSocket is a Network Communication component for Windows Developers. It runs on any 32 bit and 64 bit Windows Platform, incl. Windows 7, Windows 2008, Windows 2003, Windows 2000, Windows Vista and Windows XP.
It features many IP protocols, incl.: SSH (Secure Shell), RSH (Remote Shell), HTTP(s), FTP, ICMP Ping, NTP, SNMP v1/v2c (Get,GetNext,Set), SNMP MIB translation, SNMP Trap Sender, SNMP Trap Receiver, Telnet, DNS, TCP, UDP, IP-to-Country, Wake-On-LAN and more. Samples are included many popular development platforms, incl. Visual C# .NET, Visual Basic .NET, ASP .NET, Visual Basic, Visual C/C++, ASP, Java, Javascript, PHP, Borland Delphi, Borland C++ Builder, ColdFusion.

ActiveSocket is compliant with SNMP versions v1 and v2c. Several SNMP data types are supported, including:

  • ASN_INTEGER; Numeric values;
  • ASN_INTEGER32; Numeric values;
  • ASN_BITS; Bit values, for instance: one bit per port to see if a port is connected;
  • ASN_OCTETSTRING; Byte string;
  • ASN_NULL; Null value;
  • ASN_OBJECTIDENTIFIER; Object identifier (OID);
  • ASN_SEQUENCE; Text string;
  • ASN_IPADDRESS; IP address;
  • ASN_COUNTER32; 32 bit counter;
  • ASN_GAUGE32; 32 bit gauge;
  • ASN_TIMETICKS; Timestamps or uptime;
  • ASN_OPAQUE; Byte string;
  • ASN_COUNTER64; 64 bit counter;
  • ASN_UNSIGNED32; unsigned 32 bit numeric value.

ActiveSocket supports the following SNMP trap features:

  • SNMP v1 and SNMP v2c support;
  • Support for alphanumeric OID's (object identifier) and numeric OID's;
  • Multithreading architecture: send and/or receive SNMP traps simultaneously from one process using multiple threads;
  • Support for ports other than the default 161 and 162 ports;
  • Support for enterprise specific traps;
  • Support for SNMP v1 generic traps such as coldstart, warmstart, linkup, linkdown, authfailure and neighbourloss;
  • Send multiple data objects (variable bindings) using a single SNMP trap message.

ActiveSocket can be well integrated into VB Script environments. This document describes how ActiveSocket can be integrated into VB Script projects.

Prerequisites

IMPORTANT: Make sure that the SNMP Service is installed and running on the machine where ActiveSocket is installed. For more details, please read FAQ items Q1200010 and Q1200015.

Step 1: Download and install the ActiveSocket Toolkit

Download ActiveSocket from the ActiveXperts Download Site and start the installation. The installation guides you through the installation process.

Step 2: Create a new script

Create a new script using your favorite editor. You can simply use notepad. However, a VBScript editor is recommended, so you can browse through objects, objects properties and object functions.

You're now able to write a more advanced script to communicate using the ActiveSocket Toolkit.

Step 3: Create the ActiveSocket objects in VBScript

To send SNMP traps using VBScript, you need to declare and create the following ActiveSocket objects:

  • SnmpTrapManager; The SNMP manager which allows you to send and/or receive SNMP traps in the form of SnmpTrap objects;
  • SnmpTrap; The actual SNMP trap, this object holds some SNMP trap properties like: destination host, port and community, specific and generic trap and a timestamp;
  • SnmpObject; This object is used to hold the data to be send with the SNMP trap. These data objects are also called variable bindings.

Create a new VBScript file called demo.vbs. It is recommended to insert the following line on top of your code: 

   Option Explicit

This statement requires that all variable names be defined (with the Dim statement), to avoid simple typos that can cause incredible headaches and long debugging sessions for something that should have never happened.

Now, declare the ActiveSocket object(s):

   Dim objSnmpTrapManager
   Dim objSnmpTrap
   Dim objSnmpObject

Create the ActiveSocket object(s) like this:

   Set objSnmpTrapManager      = CreateObject( "ActiveXperts.SnmpTrapManager" )
   Set objSnmpTrap             = CreateObject( "ActiveXperts.SnmpTrap" )
   Set objSnmpObject           = CreateObject( "ActiveXperts.SnmpObject" )

Now, add the following lines to the file to have your fist ActiveSocket VBScript program:

   WScript.Echo "Version: " & objSnmpTrapManager.Version
   WScript.Echo "Expiration Date: " & objSnmpTrapManager.Expiration Date

Step 4: Send an SNMP trap message to a remote SNMP management station

You can now send SNMP trap messages to any SNMP management station or device. The following VBScript code shows how to send an SNMP trap to a remote SNMP manager: 

Option Explicit

' Declare variables
Dim objSnmpTrapManager, objSnmpTrap, objSnmpObject
Dim objConstants
Dim strHostName
Dim strCommunity

' Create a SnmpTrapOut instance
Set objSnmpTrapManager  = CreateObject( "ActiveXperts.SnmpTrapManager" )
Set objSnmpTrap         = CreateObject( "ActiveXperts.SnmpTrap" )
Set objSnmpObject       = CreateObject( "ActiveXperts.SnmpObject" )
Set objConstants        = CreateObject( "ActiveXperts.ASConstants" )

' Write some information to console
WScript.Echo "ActiveSocket " & objSnmpTrapManager.Version & " demo."
WScript.Echo "Expiration date: " & objSnmpTrapManager.ExpirationDate & vbCrLf

' Get Host and Community name
Do
   strHostName = inputbox( "Enter the hostname (a remote or local hostname)", "Input", "localhost" )
Loop until strHostName <> ""
Do
   strCommunity = inputbox( "Enter community", "Input", "public" )
Loop until strCommunity <> ""

' Initialize SNMP
objSnmpTrapManager.Initialize
WScript.Echo "Initialize, result: " & objSnmpTrapManager.LastError & " (" & objSnmpTrapManager.GetErrorDescription( objSnmpTrapManager.LastError ) & ")"
If( objSnmpTrapManager.LastError <> 0 ) Then
   WScript.Quit
End If

' Set SNMP protocol version. if not assigned, then default: asSNMP_VERSION_V2C will be used.
objSnmpTrapManager.ProtocolVersion = objConstants.asSNMP_VERSION_V2C

' Set trap properties
objSnmpTrap.Clear()

objSnmpTrap.Host      = strHostName
objSnmpTrap.Community = strCommunity
objSnmpTrap.Port      = 162

' Add first variable to trap
objSnmpObject.Clear()

objSnmpObject.OID   = ".1.3.6.1.2.1.1.5.0"
objSnmpObject.Type  = objConstants.asSNMP_TYPE_IPADDRESS
objSnmpObject.Value = "10.0.0.1"

objSnmpTrap.AddObject	( objSnmpObject )

' Add second variable to trap
objSnmpObject.Clear()

objSnmpObject.OID   = ".1.3.6.1.2.1.1.5.1"
objSnmpObject.Type  = objConstants.asSNMP_TYPE_OCTETSTRING
objSnmpObject.Value = "One two three"

objSnmpTrap.AddObject ( objSnmpObject )

' Send the trap. If you want to use another port than default SNMP trap port 162, set it as optional 2nd parameter
objSnmpTrapManager.Send objSnmpTrap

WScript.Echo "Send, result: " & objSnmpTrapManager.LastError & " (" & objSnmpTrapManager.GetErrorDescription( objSnmpTrapManager.LastError ) & ")"

objSnmpTrapManager.Shutdown
WScript.Echo "Shutdown, result: " & objSnmpTrapManager.LastError & " (" & objSnmpTrapManager.GetErrorDescription( objSnmpTrapManager.LastError ) & ")"

There are many working samples included with the product. You can also find them on the ActiveXperts FTP site: ftp.activexperts-labs.com/samples/asocket.